Vn-Screen Forum
Bạn có muốn phản ứng với tin nhắn này? Vui lòng đăng ký diễn đàn trong một vài cú nhấp chuột hoặc đăng nhập để tiếp tục.



 
Trang ChínhTrang Chính  GalleryGallery  Latest imagesLatest images  Tìm kiếmTìm kiếm  Đăng kýĐăng ký  Đăng NhậpĐăng Nhập  
Bài Viết MớiTin NóngThống kê

Share | 
 

 Chương Năm - Các loại dữ kiện (Học visual basic 6.0)

Xem chủ đề cũ hơn Xem chủ đề mới hơn Go down 
Tác giảThông điệp
TjaGoChangLj
Administrator
Administrator
TjaGoChangLj

Thanked : 14


Chương Năm - Các loại dữ kiện (Học visual basic 6.0) _
Bài gửiTiêu đề: Chương Năm - Các loại dữ kiện (Học visual basic 6.0)   Chương Năm - Các loại dữ kiện (Học visual basic 6.0) Empty15/6/2011, 10:07 pm

Khóa Hàm Thụ Visual Basic 6.0


Chương Năm - Các loại dữ kiện





Công việc chính của tất cả các
chương trình VB6 chúng ta viết là chế biến các dữ kiện để trình bày. Thí
dụ một thầy giáo dùng một chương trình để tính điểm trung bình của học
sinh trong một môn thi. Thầy tuần tự cho điểm của từng học sinh vào và
sau cùng bấm một nút bảo chuơng trình tính điểm trung bình cho cả lớp.
Chương trình sẽ display điểm thi của từng học sinh bên cạnh tên của học
sinh ấy, tổng số học sinh, tổng số điểm, điểm thấp nhất, điểm cao nhất
và điểm trung bình:
<blockquote><blockquote>
Tên họÐiểm
Lê Quang Vinh15.50
Trần văn Thành16.00
Nguyễn Thị Hương17.50
Võ Tự Cường14.00
Phạm Văn Khá18.00
Cao Xuân Tiên13.00
Tổng số học sinh:6
Tổng số điểm:94.00
Ðiểm thấp nhất:13.00
Ðiểm cao nhất:18.00
Ðiểm trung bình:15.66
</blockquote></blockquote>
Ta có thể tạm chia quá trình xử lý của một chương trình ra làm ba giai đoạn:

  1. Tiếp nhận dữ kiện: Ðây là giai đoạn ta cho dữ kiện vào chương trình (Input data) hoặc bằng cách điền vào một form, hoặc đọc dữ kiện từ một cơ sỡ dữ kiện (Database) hoặc nhận dữ kiện qua đường dây viển thông, .v.v..
  2. Chế biến dữ kiện: Một khi đã có dữ kiện đầy đủ rồi ta sẽ sắp xếp, cộng, trừ, nhân, chia theo cách đã định trước để đi đến kết quả.
  3. Trình bày, báo cáo: Kết quả cần phải được display trên màn ảnh cách gọn ghẽ, thứ tự hay được in ra, ta còn gọi là Report.

Như vậy trong mọi giai đoạn của chương trình ta đều làm việc với dữ
kiện. Trong thí dụ nói trên ta làm việc với hai loại dữ kiện: "dòng chữ" (text string) cho tên học sinh và "số" (number)
cho các điểm. Sở dĩ ta phải phân biệt các data types vì mỗi loại data
có những chức năng riêng của nó. Thí dụ ta không thể cộng hai text
string lại với nhau như hai con số, nhưng ta có thể ghép hai text string
lại với nhau, thí dụ như ghép chữ house với chữ wife thành ra chữ housewife. Chốc nữa ta sẽ bàn thêm về data types, nhưng bây giờ ta thử tìm hiểu data được chứa trong computer như thế nào.

Dữ kiện được chứa theo quy ước



Rốt cuộc lại, tất cả data đều được chứa dưới dạng các con số. Mỗi con số
đại diện cho một thứ gì đó, tùy theo quy ước của người dùng. Chúng ta
biết bộ trí nhớ (memory) của computer chứa những byte data, thí dụ như computer của bạn có 32MB, tức là khoảng hơn 32 triệu bytes. Thật ra một byte gồm có 8 bits, mỗi bit đại diện một trong hai trị số: 1 và 0, hay Yes và No , dòng điện chạy qua được hay không được .v.v.. Bit là đơn vị trí nhớ nhỏ nhất của memory.

Một byte có thể chứa một con số từ 0 đến 255, tức là 2^8 -1 (2 lũy thừa 8
bớt 1) . Khi dùng bits ta đếm các số trong hệ thống nhị phân. Nếu bạn
chưa biết nhiều thì hãy đọc bài
Hệ thống số nhị phân.

Thí dụ, khi bạn ấn nút A trên keyboard, keyboard sẽ gởi về computer con số 65 (01000001 trong nhị phân) . Nếu bạn đang dùng một Notepad chẳng hạn, bạn sẽ thấy chữ A
hiện ra. Bạn hỏi tại sao letter A được biểu diễn bằng số 65? Xin trả
lời rằng đó là quy ước quốc tế. Quy ước đuợc áp dụng cho tất cả các keys
của bàn phím đuợc gọi là ASCII. Theo quy ước nầy digit "1" được biểu diễn bằng con số 48 (00110001) và nút Enter bằng số 13 (00010011).

Chắc có lẽ bạn đã đoán ra rằng theo quy ước ASCII, mỗi pattern (dạng)
của 8 bits (1 byte) sẽ biểu diễn một text character. Bây giờ ta thử
tính xem các mẫu tự alphabet và digits sẽ chiếm bao nhiêu patterns trong
số 256 patterns ta có thể biểu diễn bằng 1 byte. Từ A đến Z có 26
characters. Nhân đôi để tính cho lowercase (chữ thường) và uppercase
(chữ hoa) thành ra 52. Cộng với 10 digits từ 0 đến 9 thành ra 62. Cộng
thêm chừng ba mươi ngoài các symbols ta dùng chỉ đến chừng 100 patterns
mà thôi. Tức là nói một cách khác nếu số patterns ta dùng dưới 128 thì
chỉ cần 7 bits (chớ không đến 8 bits) cũng đủ rồi.

Thật ra từ nãy giờ ta chỉ nói đến các characters có thể display hay in ra đuợc (printable characters).
Các con số ASCII
từ 1 đến 31 không in ra đuợc nhưng đuợc dùng một cách đặc biệt, thí dụ
như 7 là BELL (tiếng bíp), 12 là qua trang mới, 10 là xuống hàng, 13 là
Enter/CarriageReturn, .v.v.. Chúng đuợc gọi là các Control Characters.
Khi xem qua các Font chữ trong Windows, bạn sẽ thấy cho cùng một con số
65, không phải Font nào cũng display chữ A. Thí dụ như Font Symbol nó
display đủ thứ dấu hiệu. Ðiểm nầy nhắc chúng ta lại rằng mối liên hệ
giữa một con số bên trong (internal number) và một dấu hiệu được display
chẳng qua là một quy ước mà thôi.

Giả sử chúng ta dùng những con số ASCII còn trống để biểu diễn các chữ
Việt Nam có dấu và chịu khó ngồi vẽ thêm các Vietnamese characters cần
thiết trong Font thì ta có thể display chữ Việt đuợc. Ðúng vậy, đó là
cách các khoa học gia Việt Nam đã dùng để display tiếng Việt trong
MSWindows, điển hình là VPS, VISCII.

Không phải memory của computer chỉ chứa data thường mà thôi. Nó còn chứa chính chương trình, gọi là executable code trong machine language
(ngôn ngữ của máy). Ngày xưa, khi memory của computer còn ít, người ta
có thể cho vào từng byte của code một chương trình. Họ lập trình bằng Assembly language.
Mỗi hàng code trong Assembly language có thể đuợc dịch thẳng ra code
trong machine language. CPU của mỗi manufacturer có một assembly
language khác nhau. Các công ty Computer nổi tiếng ngày xưa là IBM,
Digital, CDC. Ðến thời buổi Microcomputer ta có Motorola, Intel, nhưng
tựu trung, nếu không biết trước code của machine language nào, ta không
thể nhận ra gì cả khi nhìn vào memory dump (in ra snapshot của memory)
của một computer.

Text String


Nếu ta ghép nhiều characters lại với
nhau ta có một Text String. Trong VB6, Text String được viết thành một
dãy chữ với dấu ngoặc kép ở hai đầu, thí dụ: "Hello, world"
Tưởng tượng ta ghép ba mẫu tự alphabet đầu tiên lại với nhau: ABC,
trong memory Text String nầy được biểu diễn bằng con số
010000010100001001000011 (trong binary) hay 414243 (trong Hex, mỗi nhóm 4
bits tương đuơng với một Hex digit).
VB6 cho ta những Function rất tiện lợi để làm việc với Text String. Ðể ghép hai Text String lại với nhau ta dùng operator &. Thí dụ:
<blockquote><blockquote>
FirstWord = "Hello"
SecondWord = "World"
Greeting = FirstWord & SecondWord ' Greeting bây giờ là "HelloWorld"


nếu muốn có một blank space ở giữa hai chữ trên ta viết như sau:

Greeting = FirstWord & " " & SecondWord
</blockquote></blockquote>
Muốn biết một Text String đang chứa bao nhiêu characters ta dùng Function Len. Thí dụ:
<blockquote><blockquote>
Greeting = "Hi John!"

iLen = Len(Greeting) ' iLen bây giờ bằng 8
</blockquote></blockquote>
Ðể trích ra một phần của Text String (tức là trích ra một SubString) ta dùng các Functions Left, Right và Mid.
<blockquote><blockquote>
Today = "24/05/2001"
' Lấy ra 2 characters từ bên trái của String Today
StrDay = Left(Today,2) ' StrDay bây giờ bằng "24"
' Lấy ra 4 characters từ bên phải của String Today
StrYear = Right(Today,4) ' StrYear bây giờ bằng "2001"
' Lấy ra 2 characters bắt đầu từ character thứ tư của String Today, character đầu tiên từ bên trái là thứ nhất
StrMonth = Mid(Today,4,2) ' StrMonth bây giờ bằng "05"
' Lấy ra phần còn lại bắt đầu từ character thứ tư của String Today
StrMonthYear = Mid(Today,4) ' StrMonthYear bây giờ bằng 05/2001"
</blockquote></blockquote>
Trong tất cả các trường hợp trên Text String Today không hề bị thay đổi, ta chỉ trích ra một SubString của nó mà thôi.
Nếu ta muốn thay đổi chính Text String Today ta có thể assign value mới cho nó hay dùng Function Mid ở bên trái dấu Assign (=), thí dụ:
<blockquote><blockquote>
Today = "24/05/2001"
' Thay thế character thứ 3 của Today bằng "-"
Mid(Today,3,1) = "-"
' Thay thế 2 characters bắt đầu từ character thứ 4 của Today bằng "10"
Mid(Today,4,2) = "10"
' Thay thế character thứ 6 của Today bằng "-"
Mid(Today,6,1) = "-" ' Today bây giờ bằng "24-10-2001"

Ta cũng có thể đạt được kết quả như trên bằng cách lập trình như sau:

Today = "24/05/2001"
Today = Left(Today,2) & "-10-" & Right(Today,4)
</blockquote></blockquote>
Ngoài ra có hai Function rất thông dụng cho Text String là InstrReplace. Instr cho ta vị trí (position) của một pattern trong một Text String. Thí dụ ta muốn biết có dấu * trong một Text String hay không:
<blockquote><blockquote>
myString = "The *rain in Spain mainly..."
Position = Instr(myString,"*") ' Position sẽ là 5
Nếu trong myString không có dấu "*" thì Position sẽ bằng 0


Bây giờ ta thử tách ra Key và Value trong thí dụ sau:
KeyValuePair = "BeatlesSong=Yesterday"
Pos = Instr(KeyValuePair, "=")
Key = Left(KeyValuePair, Pos-1)
Value = Mid(KeyValuePair, Pos+1)

</blockquote></blockquote>
Muốn thay đổi tất cả dấu "/" thành dấu "-" trong một Text String ta có thể dùng Function Replace như sau:
<blockquote><blockquote>
Today = "24/05/2001"
Today = Replace (Today, "/", "-")
</blockquote></blockquote>
Muốn biết trị số ASCII của một character ta dùng Function Asc và ngược lại để có một Text Character với một trị số ASCII nào đó ta dùng Function Chr.
<blockquote><blockquote>
ASCIINumberA = Asc("A") ' ASCIINumberA bây giờ bằng 65
LineFeedChar = Chr(10)
StrFive = Chr(Asc("0") + 5) ' ta có digit "5"
</blockquote></blockquote>
Text String trong VB6 dùng một byte cho mỗi ASCII character. Sau nầy khi
ta lập trình trong VB7, một character có thể là Unicode character,
trong trường hợp đó nó được biểu diễn bằng 2 bytes. VB6 không support
Unicode nên không phải là môi trường thích hợp để lập trình cho Unicode
tiếng Việt. Trong VB7 mỗi loại Text String có Encoding method riêng của
nó để yểm trợ Unicode nếu cần.

Các loại số


Từ nãy giờ ta chỉ bàn về Text String và cách chứa của nó trong memory. Nên nhớ rằng "123"
là một Text String và nó được biểu diễn trong memory bằng con số
001100010011001000110011 trong Binary hay 313233 trong Hex. Như vậy có
cách nào biểu diễn con số 123 mà không dùng Text String không? Dĩ nhiên
là được. Con số 123 là 7B trong Hex hay 01111011 trong Binary,
và ta có thể chứa con số nầy vừa tiện lợi để làm toán, vừa ít tốn memory
hơn là chứa Text String "123". Nhớ là ta cần Text String để display hay
in ra, còn khi làm toán cộng, trừ, nhân, chia ta lại cần cái dạng raw
number hay internal number của nó.

Ðể convert một Text String ra Internal number ta có thể dùng các Functions Val, CInt(ra Integer) hay CSng(ra Single). Ngược lại, để convert từ internal number ra Text String ta có thể dùng Function CStr.
<blockquote><blockquote>

Dollars = "500"
ExchangeRatePerDollar = "7000"
tempValue= Val(Dollars) * Val(ExchangeRatePerDollar)
VNDong = CStr(tempValue)
MsgBox "Amount in VN Dong is " & VNDong
</blockquote></blockquote>
Thật ra VB6 support nhiều loại data để dùng chứa những con số. Trước hết ta có số nguyên (IntegerLong).
Cùng là số nguyên nhưng Integer dùng 2 bytes trong memory để chứa một
con số nguyên từ -32768 đến 32767. Ðể ý là 32768 = 2^15 (2 lũy thừa 15)
, tức là trong memory các con số từ 32768 đến 65535 được dùng để biểu
diễn các số âm. Một lần nữa, nhớ rằng một con số trong memory để biểu
diễn một thứ gì chẳng qua chỉ là theo quy ước mà thôi.

Còn Long
dùng 4 byte để để chứa một con số nguyên từ -2147483648 đến
2147483647. Nếu bạn dùng Integer mà bị Oveflow error khi làm toán nhân
thì assign các con số vào một Long variable (sẽ cắt nghĩa variable sau
nầy) TRƯỚC KHI làm toán nhân chớ đừng để kết quả một bài toán nhân quá lớn trước khi Assign nó vào một Long variable. Thí dụ:

<blockquote><blockquote>
' Thay gì viết
Dim Result as Long
Result = 30345 * 100 ' sẽ bị overflow error

' Hãy viết như sau:
Dim Result as Long
Result = 30345
Result = Result * 100 ' không bị overflow error
</blockquote></blockquote>
Ðể tính toán cho chính xác ta cần một loại data có thể chứa số sau decimal point. VB6 cho ta SingleDouble. Single dùng 4 bytes, Double dùng 8 bytes. Thông thường, bạn sẽ hiếm khi cần nhắc đến Double.
Khi display một số Single hay Double bạn cần dùng Function Format để convert từ Single ra Text String một cách uyển chuyển. Thí dụ
<blockquote><blockquote>
Dollars = "500.0"
ExchangeRatePerDollar = "7000.0"
'Dùng Function CSng để convert String ra Single
tempValue= CSng(Dollars) * CSng(ExchangeRatePerDollar)
'Dùng Function Format để có các dấu phẩy ở ngàn và triệu và phải có 2 digits sau decimal point.
VNDong = Format (tempValue, "#,###,###.00")
MsgBox "Amount in VN Dong is " & VNDong
</blockquote></blockquote>
VB6 cho ta hai cách chia, đó là / dùng cho Single/Double và \ dùng cho Integer.
<blockquote><blockquote>
5 / 3 cho ta 1.6666666
5 \ 3 cho ta 1
</blockquote></blockquote>
Function Round đuợc dùng để bỏ bớt các con số nằm phía sau decimal point. Thí dụ:
<blockquote><blockquote>
Round ( 12.3456789, 4 )
chỉ giữ lại 4 con số sau decimal point và cho ta 12.3457
</blockquote></blockquote>
Numeric data type Currency chỉ chứa nhất định 4 số sau decimal point. Nó không có ích lợi đặc biệt gì.

Variable


Variable là những chỗ chứa data tạm thời trong memory để ta dùng trong quá trình biến chế data của chương trình. Khi ta Declare (khai báo)
một variable loại data gì là ta dành ra một chỗ trong memory để chứa
một miếng data loại ấy. Nhớ là tùy theo loại data ta sẽ cần nhiều hay ít
memory, một Interger chỉ cần 2 bytes, còn một Single cần đến 4 bytes,
trong khi một String thì cần nhiều memory hơn nữa. Thí dụ như:
<blockquote><blockquote>
Dim strFullName as String
Dim ICount as Integer
Dim sRate as Single
</blockquote></blockquote>
Khi bạn tìm cách cho hai data type khác nhau làm việc, thí dụ như làm toán chia một Text String bởi một con số thì có thể bị Mixed mode error.
Tuy nhiên nếu Text String ấy gồm những digits thì có thể VB6 sẽ tự động
convert Text String ra một con số trước khi dùng nó trong một bài toán.
Ngược lại, dĩ nhiên ta không thể ghép một con số vào một Text String,
nhưng VB6 có thể convert con số ra một Text String of digits trước khi
ghép Text String ấy vào String kia.
Mặc dầu VB6 rất tế nhị trong việc đoán ra ý định của chúng ta trong khi
coding nhưng ta phải thận trọng trong cách dùng Data type để tránh gặp
phải những bất ngờ.

Vấn đề đặt tên cho variable rất quan trọng. Bạn nên đặt tên variable và
các Function, Sub như thế nào để khi đọc code ta thấy dễ hiểu như đọc
một bài luận văn. Thường thường, để dễ nhận diện data type của một
variable người ta gắn phía trước tên variable các prefix như str cho String, I cho Integer, s
cho Single ..v.v.. Khi ráp nhiều chữ rời thành tên một variable,
thường thường người ta làm cho letter đầu tiên của mỗi chữ thành ra Hoa (Capital), thí dụ như TotalSalesOfTheMonth.

Có một Tip nho nhỏ là đừng ngại đặt tên variable quá dài. Khi đánh máy nữa chừng tên của một variable bạn có thể đánh Ctrl-Space để IDE đánh nốt phần còn lại của tên variable, nếu không có sự trùng hợp với một tên variable/Sub/Function nào khác.


Nếu công tác lập trình giống như nấu ăn, bạn có thể nghĩ đến variable
như các cái rổ, thau ta cần có để việc chuẩn bị thức ăn được tiện lợi.
Trước khi bắt tay vào công tác ta xin với chủ nhà cho mình bao nhiêu cái
rổ, thau, thún .v.v..(đó là Declare variables). Ta để mỗi loại
thức ăn vào một rổ hay thau khác nhau, chớ không để thịt chung với rau
cải (cũng như không thể cộng Text String với con số). Khi ta bỏ thêm một
trái cà vào rổ cà thì số trái cà trong rổ tăng lên 1. Một lát sau ta
lấy ra vài trái cà để dùng thì số trái cà trong rổ bị giảm đi. Khi không
cần dùng nữa ta bỏ hay cất mấy trái cà còn lại rồi dẹp cái rổ đi chỗ
khác.

Trị giá của một variable thường hay thay đổi trong quá trình xử lý data.
Ðến một lúc nào đó variable không còn hiện hữu. Phạm vi hoạt động của
một variable được gọi là scope. Nếu code nằm ngoài phạm vi của
một variable thì không thể dùng đến variable ấy được. Dưới đây là
listing của một chương trình VB6 ngắn:
<blockquote><blockquote>
Option Explicit
Dim iCount As Integer
Dim X As Integer
Dim Y As Integer
Private Sub CmdIncreX_Click()
iCount = iCount + 1
X = X + 1
If X = 80 Then
X = 0
Y = Y + 1
End If
End Sub
Private Sub CmdIncreY_Click()
Dim Y
iCount = iCount + 1
Y = Y + 1
End Sub
</blockquote></blockquote>
Trong listing trên Scope của iCount, X, Y là toàn bộ listing, tức là ở
đâu cũng có thể nói đến, dùng, thấy các variables đó. Tuy nhiên trong
Sub CmdIncreY-Click() có declare một variable Y. Scope của variable nầy
là chỉ nội bộ, tức là bên trong Sub CmdIncreY-Click() mà thôi. Chẳng
những thế, cái local (địa phương) variable Y nầy còn che cái global
variable Y nữa, tức là bên trong Sub CmdIncreY-Click() ta chỉ thấy
local variable Y mà không thấy global variable Y. Một khi execution
trong Sub CmdIncreY-Click() đã kết thúc thì local variable Y cũng biến
mất luôn. Nếu bạn muốn khi trở lại execute Sub CmdIncreY-Click() mà
local variable Y vẫn còn y nguyên với giá trị gì nó có từ trước, bạn nên
Declare rằng nó Static, như:
<blockquote><blockquote>
Static Y as Integer
</blockquote></blockquote>
Nói tóm lại, Local variable của Sub hay Function chỉ hoạt động và hiện
hữu bên trong Sub/Function. Global variable của một Form hay Module thì
áp dụng cho cả Form/Module trừ khi bị che lại bởi một local variable có
cùng tên bên tron một Sub/Function. Ngoài ra khi ta Declare một Global
variable là Public thì các Form/Module khác cũng thấy và dùng nó được
luôn. Theo nguyên tắc của Software Engineering thì vì lý do an ninh ta
chỉ cho phép người khác thấy cái gì cần thấy thôi. Do đó, ta không nên
Declare các variable Public bừa bãi, nhỡ khi có một variable bị
thay đổi value một cách bí mật mà ta không đoán đuợc thủ phạm là ai. Nhớ
rằng Declare Public cũng giống như để nhà không đóng cửa vậy.

Ngoài ra, câu Option Explicit ở đầu Listing được dùng để tuyên bố
rằng tất cả mọi variables dùng trong Form/Module đều cần phải được
Declare. Nhớ là VB6 không đòi hỏi ta phải Declare một variable trước
khi dùng nó. Thường thường, tùy theo tình huống, VB6 có thể đoán ra
được Data Type của variable khi ta dùng nó lần đầu tiên. Nếu code đòi
hỏi value của một variable khi nó đuợc dùng lần đầu thì VB6 tự động coi
nó như một Empty String (String không có character nào cả, viết là ""
) nếu nó là Text String Data type hay con số 0 nếu nó là một con số.
Ðiều nầy rất là tiện lợi. Tuy nhiên, nếu ta sơ ý đánh vần lộn một
variable thì VB6 tự động initialise nó ra Empty String hay 0. Ðây có
thể không phải là điều ta muốn. Nếu có dùng Option Explicit thì việc nầy
sẽ bị lộ tẩy ngay vì tất cả mọi variable đều phải đuợc tuyên bố chính
thức. Do đó, đã là VB6 programmer, bạn hãy xem việc dùng Option Explicit
như là một điều răn của Chúa, hãy vâng giữ cách trung tín.

Ngày và Giờ


Có một loại data type đuợc dùng để chứ cả ngày lẫn giờ, đó là Date. Ta có thể biết hiện thời là ngày nào, mấy giờ bằng cách gọi Function Now. Sau đó ta dùng các Function Day, Month và Year để lấy ra ngày, tháng và năm như sau:
<blockquote><blockquote>
Private Sub CmdCheckDate_Click()
Dim dDate As Date
If IsDate(txtDate.Text) Then ' eg: txtDate = "26/12/01"
dDate = CVDate(txtDate.Text) ' convert a Text String to internal Date using Function CVDate
' Day, Month and Year are automatically converted to String
MsgBox "Day = " & Day(dDate) & ", Month = " & Month(dDate) & ", Year = " & Year(dDate)
Else
MsgBox "Invalid date. Please try again."
End If
End Sub
</blockquote></blockquote>
Trong Listing trên ta dùng Function IsDate để kiểm xem txtDate.text có
hợp lệ không. Lưu ý là IsDate không phân biệt ngày theo Mỹ (dạng
mm/dd/yy) hay theo Âu Châu (dạng dd/mm/yy), do đó dùng IsDate trong công
việc kiểm soát nầy không an toàn lắm.
Ðể display ngày giờ theo đúng cách mình muốn bạn có thể dùng Function Format như sau:
<blockquote><blockquote>
MsgBox "NOW IS " & Format (Now, "ddd dd-mmm-yyyy hh:nn:ss")
' will display
NOW IS Fri 08-Jun-2001 22:10:53
</blockquote></blockquote>
Bạn có thể dùng mm để display tháng bằng một con số. Sở dĩ ta dùng nn thay vì mm cho phút là vì mm đã được dùng cho tháng.
Ta có thể thêm bớt các đơn vị của ngày, tháng, v.v. bằng cách dùng Function DateAdd. Thí dụ:
<blockquote><blockquote>
Private Sub CmdNextMonth_Click()
txtDate.Text = Format(Now, "dd/mm/yy") ' 08/06/01
txtNextMonth.Text = DateAdd("m", 1, CVDate(txtDate.Text))
' txtNextMonth.text will show 8/07/2001
End Sub
</blockquote></blockquote>
Dưới đây là cách tính ra ngày cuối của tháng nầy:
<blockquote><blockquote>
Private Sub CmdLastDayOfMonth_Click()
Dim dNextMonthDate, dFirstDayNextMonth
dNextMonthDate = DateAdd("m", 1, Now) ' Add one month to get same day next month
' Get first day of next month
dFirstDayNextMonth = 1 & "/" & Month(dNextMonthDate) & "/" & Year(dNextMonthDate)
' Subtract one day to get Last day of this month
txtLastDayOfMonth.Text = DateAdd("d", -1, CVDate(dFirstDayNextMonth))
End Sub
</blockquote></blockquote>
Ta có thể tính khoảng cách giữa hai ngày theo đơn vị ngày, tháng v.v.. bằng cách dùng Function DateDiff. Kết quả có thể là âm, dương hay 0 tùy theo ngày nào trể hơn. Thí dụ khoảng cách giữa hai ngày theo đơn vị tháng:
<blockquote><blockquote>
DateDiff("m", Now, CVDate(dNextMonthDate))
</blockquote></blockquote>
Trong chương tới ta sẽ học về Data types Boolean, Variant và Data Array.
Chữ Ký Cá Nhân
Về Đầu Trang Go down
 

Chương Năm - Các loại dữ kiện (Học visual basic 6.0)

Xem chủ đề cũ hơn Xem chủ đề mới hơn Về Đầu Trang 
Trang 1 trong tổng số 1 trang

Permissions in this forum:Bạn không có quyền trả lời bài viết
Vn-Screen Forum :: Công Nghệ Thông Tin :: Khu Lập Trình :: Visual Basic-
VN-SCREEN.DARKBB.COM
Design by N.H.M - Developed by Vn-Screen Member
Free forum | ©phpBB | Free forum support | Báo cáo lạm dụng | Thảo luận mới nhất